nvimpager but using neovim from some specific nixcats flake

[0xferrous]

https://github.com/lucc/nvimpager is interesting but i dont like the default styling, etc. it comes with. I think it can be interesting if you can take the neovim output from something like github:BirdeeHub/nixCats-nvim?dir=templates/example and use that as the launcher for the pager.

[0xferrous]

this kind of works:

((nvimpager.override { 
  neovim = inputs.nixCats.packages.${pkg.system}.default; 
}).overrideAttrs { 
  doCheck = false; 
})

had to remove the preCheck tests because some of them failed.

[BirdeeHub]

So, thats 3 more ways to make it work I guess. 1, do what you are doing but make sure your package has an executable named nvim in it, 2, wrap it with the env var, 3, copy their flake in overrideAttrs but use your own nvim

Theres probably more.

[0xferrous]

So, something more like this would likely be better

(pkgs.runCommand "nvimpager" {
  nativeBuildInputs = [ pkgs.makeBinaryWrapper ];
} (let
  nvimpkg = inputs.nixCats.packages.${pkg.system}.default;
  wrapperArgs = [
   "--set" "NVIMPAGER_NVIM" "${nvimpkg}/bin/${nvimpkg.nixCats_packageName}"
  ];
in ''
  mkdir -p $out
  cp -r "${inputs.nvimpager.packages.${system}.default}"/* $out
  wrapProgram "$out/bin/nvimpager" ${lib.escapeShellArgs wrapperArgs}
''))

this worked too.

You could also borrow the logic from their flake and do this, fixing the issue while leaving their test dependencies intact.

This theoretically is not as good as wrapping it like above, because it causes rebuild of nvimpager, as nvimpager misses the cache if you override it.

However, nvimpager is from a flake and is not cached, so that does not matter much, it was not cached anyway.

(nvimpager.overrideAttrs { 
  preBuild = let
    nvimpkg = inputs.nixCats.packages.${pkg.system}.default;
  in ''
    patchShebangs nvimpager
    substituteInPlace nvimpager --replace ':-nvim' ':-${nvimpkg}/bin/${nvimpkg.nixCats_packageName}'
  '';
})

this still failed the tests

[BirdeeHub]

Huh. Surprising. IDK then. Guess that one doesnt work idk. I havent actually ran any of this code I wrote here in this thread lol

I edited my wrapped version (the second one) a bit to be a bit cleaner btw since you got to mess with it. Removes the copy, uses symlinkJoin instead.

(pkgs.symlinkJoin {
  name = "nvimpager";
  paths = [ inputs.nvimpager.packages.${pkgs.system}.default ];
  nativeBuildInputs = [ pkgs.makeBinaryWrapper ];
  postFixup = let
    nvimpkg = inputs.nixCats.packages.${pkgs.system}.default;
    wrapperArgs = [
      "--set" "NVIMPAGER_NVIM" "${nvimpkg}/bin/${nvimpkg.nixCats_packageName}"
    ];
  in ''
    wrapProgram "$out/bin/nvimpager" ${lib.escapeShellArgs wrapperArgs}
  '';
})

[0xferrous]

yeah i dont have the mad nix skills yet, and docs for lib and functions seem bad or difficult to find. but whatever you wrote works so i just jammed it in my config lol. thanks!

[BirdeeHub]

https://nixos.wiki/wiki/Nix_Cookbook#Wrapping_packages

Heres where I got the info for how to make the second one. (I mean, I knew the info, but there's where I usually go for reference)

makeWrapper and makeBinaryWrapper are indeed poorly documented. You need to go to the files and look at the comments unfortunately

https://github.com/NixOS/nixpkgs/blob/master/pkgs/build-support/setup-hooks/make-wrapper.sh

https://github.com/NixOS/nixpkgs/blob/master/pkgs/by-name/ma/makeBinaryWrapper/make-binary-wrapper.sh

Edit: and I am also apparently still the most recent person to have made a commit to either of them, so thats cool I guess.

As far as builtins and lib functions go, I usually just google "nix builtin and lib" and get https://teu5us.github.io/nix-lib.html as the top result.