[Cranelift] (x < y) & (x ≠ -1) = (x < y) (#11996)

* [Cranelift] `(x < y) & (x ≠ -1) = (x < y)`

* fix test

Author: bongjunj

cranelift/codegen/src/opts/icmp.isle

@@ -350,3 +350,29 @@
   (if-let true (i64_lt x 0))
   (iconst_u ty 0))
 
+;; (x < y) & (x ≠ -1) = (x < y)
+(rule
+  (simplify (band ty (ne ty x (iconst_s _ -1)) (ugt ty y x)))
+   (ult ty x y))
+(rule
+  (simplify (band ty (ne ty x (iconst_s _ -1)) (ult ty x z)))
+   (ult ty x z))
+(rule
+  (simplify (band ty (ne ty (iconst_s _ -1) x) (ugt ty y x)))
+   (ult ty x y))
+(rule
+  (simplify (band ty (ne ty (iconst_s _ -1) x) (ult ty x z)))
+   (ult ty x z))
+(rule
+  (simplify (band ty (ugt ty x y) (ne ty y (iconst_s _ -1))))
+   (ult ty y x))
+(rule
+  (simplify (band ty (ugt ty x y) (ne ty (iconst_s _ -1) y)))
+   (ult ty y x))
+(rule
+  (simplify (band ty (ult ty x y) (ne ty x (iconst_s _ -1))))
+   (ult ty x y))
+(rule
+  (simplify (band ty (ult ty x y) (ne ty (iconst_s _ -1) x)))
+   (ult ty x y))
+

cranelift/filetests/filetests/egraph/icmp.clif

@@ -405,3 +405,19 @@ block0(v0: i32):
 ;     return v9  ; v9 = 0
 ; }
 
+;; (x <u y) & (x != -1) => (x <_u y)
+function %test_ult_ne_minus_one(i32, i32) -> i8 fast {
+block0(v0: i32, v1: i32):
+    v2 = icmp ult v0, v1
+    v3 = iconst.i32 -1
+    v4 = icmp ne v0, v3
+    v5 = band v2, v4
+    return v5
+}
+
+; function %test_ult_ne_minus_one(i32, i32) -> i8 fast {
+; block0(v0: i32, v1: i32):
+;     v6 = icmp ult v0, v1
+;     return v6
+; }
+

cranelift/filetests/filetests/runtests/icmp.clif

@@ -159,3 +159,14 @@ block0(v0: i32):
 
 ; run: %test_ult_sgt_neg_const_x(42) == 0
 
+;; (x <u y) & (x != -1) => (x <_u y)
+function %test_ult_ne_minus_one(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+    v2 = icmp ult v0, v1
+    v3 = iconst.i32 -1
+    v4 = icmp ne v0, v3
+    v5 = band v2, v4
+    return v5
+}
+; run: %test_ult_ne_minus_one(3, 5) == 1
+; run: %test_ult_ne_minus_one(-1, 1) == 0