flake: add template

Author: pinpox

flake.nix

@@ -199,6 +199,19 @@
       # Use nixpkgs-fmt for 'nix fmt'
       formatter.x86_64-linux = nixpkgs.legacyPackages.x86_64-linux.nixfmt-rfc-style;
 
+      # Each subdirectory in ./templates/<template-name> is a
+      # template, which can be used for new proects with:
+      # `nix flake init`
+      templates = builtins.listToAttrs (
+        map (name: {
+          inherit name;
+          value = {
+            path = ./templates + "/${name}";
+            description = (import (./templates + "/${name}/flake.nix")).description;
+          };
+        }) (builtins.attrNames (builtins.readDir ./templates))
+      );
+
       # Output all modules in ./modules/<module-name> to flake. Modules should be in
       # individual subdirectories and contain a default.nix file.
       # Each subdirectory in ./modules/<module-name> is a nixos module

home-manager/modules/shell/default.nix

@@ -71,6 +71,10 @@ in
     pinpox.defaults.shell.abbrev-aliases = [
 
       # Aliases expanded only at beginning of lines
+      {
+        alias = "flake-init";
+        command = "nix flake init -t github:pinpox/nixos";
+      }
       {
         alias = "g";
         command = "git";

templates/default/flake.nix

@@ -0,0 +1,63 @@
+{
+  description = "A simple Go package";
+
+  # Nixpkgs / NixOS version to use.
+  inputs.nixpkgs.url = "nixpkgs/nixos-unstable";
+
+  outputs = { self, nixpkgs }:
+    let
+
+      # to work with older version of flakes
+      lastModifiedDate = self.lastModifiedDate or self.lastModified or "19700101";
+
+      # Generate a user-friendly version number.
+      version = builtins.substring 0 8 lastModifiedDate;
+
+      # Helper function to generate an attrset '{ x86_64-linux = f "x86_64-linux"; ... }'.
+      forAllSystems = nixpkgs.lib.genAttrs nixpkgs.lib.systems.flakeExposed;
+
+      # Nixpkgs instantiated for supported system types.
+      nixpkgsFor = forAllSystems (system: import nixpkgs { inherit system; });
+
+    in
+    {
+
+      # Provide some binary packages for selected system types.
+      packages = forAllSystems (system:
+        let
+          pkgs = nixpkgsFor.${system};
+        in
+        {
+          default = pkgs.buildGoModule {
+            pname = "go-hello";
+            inherit version;
+            # In 'nix develop', we don't need a copy of the source tree
+            # in the Nix store.
+            src = ./.;
+
+            # This hash locks the dependencies of this package. It is
+            # necessary because of how Go requires network access to resolve
+            # VCS.  See https://www.tweag.io/blog/2021-03-04-gomod2nix/ for
+            # details. Normally one can build with a fake hash and rely on native Go
+            # mechanisms to tell you what the hash should be or determine what
+            # it should be "out-of-band" with other tooling (eg. gomod2nix).
+            # To begin with it is recommended to set this, but one must
+            # remember to bump this hash when your dependencies change.
+            # vendorHash = pkgs.lib.fakeHash;
+
+            vendorHash = "sha256-pQpattmS9VmO3ZIQUFn66az8GSmB4IvYhTTCFn6SUmo=";
+          };
+        });
+
+      # Add dependencies that are only needed for development
+      devShells = forAllSystems (system:
+        let
+          pkgs = nixpkgsFor.${system};
+        in
+        {
+          default = pkgs.mkShell {
+            buildInputs = with pkgs; [ go gopls gotools go-tools ];
+          };
+        });
+    };
+}