[tmva][sofie] Require onnx>=1.19.1 for tests

In commit 178a9f9, I activated several SOFIE tests by moving the SOFIE
PyTorch and Keras parsers out of `tmva/pymva`, because SOFIE and PyMVA
are unrelated and we lost test coverage for these SOFIE parsers, because
`tmva-pymva` is always disabled.

But as reported in #20571, we now see SOFIE test failures on macOS
because it is not possible to fully resolve the required Python
environment. The problem was that we implicitly required `onnx>=1.19.1`
for the SOFIE tests to pass, but this can't be installed on macOS
because the transient update of `ml_dtypes` is conflicting with the
current version of the `tensorflow` package.

To get out of this, this commit suggests to only enable the SOFIE
PyTorch/Keras parser tests if `onnx>=1.19.1`, with a warning otherwise.
This is the solution with the least test coverage regression. There is
even no coverage regression at all, if you compare to the state before
178a9f9 a few days ago.

We should also consider to require `onnx>=1.19.1` in our
`requirements.txt` in the future, so our users don't face similar
trouble. But this should only be done once we are sure that it can also
be installed on macOS without breaking something else.

Closes #20571.

Author: guitargeek

tmva/sofie/test/CMakeLists.txt

@@ -108,8 +108,32 @@ endif()
 # Look for needed Python modules
 ROOT_FIND_PYTHON_MODULE(torch)
 ROOT_FIND_PYTHON_MODULE(keras)
+ROOT_FIND_PYTHON_MODULE(onnx)
 
-if (ROOT_TORCH_FOUND)
+
+# Some tests need to be disabled when the onnx version is too low, because then
+# onnx is not compatible with certain PyTorch or TensorFlow versions.
+# See also: https://github.com/root-project/root/issues/20571
+#
+# TODO: We can't enforce this minimum onnx version in the global
+# requirements.txt yet, because the transient update of ml_dtypes is
+# conflicting with the current version of the tensorflow package on the macOS
+# runners. Once we have installed onnx>=1.19.1 on all of our CI nodes that
+# install onnx, we should also consider requiring this minimum version from our
+# users, se they don't face bad surprises like:
+#   https://github.com/onnx/onnx/issues/7249
+set(minimum_onnx_version "1.19.1")
+if (NOT DEFINED ROOT_ONNX_VERSION)
+  message(WARNING "onnx found, but version unknown — cannot verify compatibility.")
+  set(minimum_onnx_found TRUE) # In this case we assume it is of the right version
+elseif (ROOT_ONNX_VERSION VERSION_LESS ${minimum_onnx_version})
+  message(WARNING "onnx version ${ROOT_ONNX_VERSION} found, but we only support onnx>=${minimum_onnx_version} for compatibility reasons. Some TMVA-SOFIE tests will be disabled.")
+  set(minimum_onnx_found FALSE)
+else()
+  set(minimum_onnx_found TRUE)
+endif()
+
+if (minimum_onnx_found AND ROOT_TORCH_FOUND)
   configure_file(Conv1dModelGenerator.py  Conv1dModelGenerator.py COPYONLY)
   configure_file(Conv2dModelGenerator.py  Conv2dModelGenerator.py COPYONLY)
   configure_file(Conv3dModelGenerator.py  Conv3dModelGenerator.py COPYONLY)
@@ -129,8 +153,8 @@ if (ROOT_TORCH_FOUND)
   endif()
 endif()
 
-# Any reatures that link against libpython are disabled if built with tpython=OFF
-if (tpython AND ROOT_TORCH_FOUND AND BLAS_FOUND)
+# Any features that link against libpython are disabled if built with tpython=OFF
+if (minimum_onnx_found AND tpython AND ROOT_TORCH_FOUND AND BLAS_FOUND)
   configure_file(generatePyTorchModelClassification.py generatePyTorchModelClassification.py COPYONLY)
   configure_file(generatePyTorchModelMulticlass.py generatePyTorchModelMulticlass.py COPYONLY)
   configure_file(generatePyTorchModelRegression.py generatePyTorchModelRegression.py COPYONLY)
@@ -151,8 +175,8 @@ if (tpython AND ROOT_TORCH_FOUND AND BLAS_FOUND)
 endif()
 
 
-# Any reatures that link against libpython are disabled if built with tpython=OFF
-if (tpython AND ROOT_KERAS_FOUND AND BLAS_FOUND)
+# Any features that link against libpython are disabled if built with tpython=OFF
+if (minimum_onnx_found AND tpython AND ROOT_KERAS_FOUND AND BLAS_FOUND)
 
   set(unsupported_keras_version "3.10.0")